@rem ################################################################
@rem ### Sendet eine Mail mit übergebenen Informationen aus POC32 ###
@rem ###             (c) faboi - funkmeldesystem.de               ###
@rem ################################################################
@echo off
chcp 28591

rem ######## EINSTELLUNGEN ########

rem --- Pfad zum Programm ---
set dir=C:\Ablage\Mail_FMS32\

rem --- Feuerwehrname ---
set name="Feuerwehr Musterstadt"

rem --- Email-Einstellungen ---
set absender="Max Muster <max@muster.de>"
set empfaenger="Max Muster <max@muster.de>"
set smtp-server=smtp.muster.de
set user=XXXXXXXXXXXX
set passwort=XXXXXXXXXXXX

rem ######## EINSTELLUNGEN ENDE ########



if exist %dir%body.txt goto ende

echo Email wird generiert ...
echo %name% - Alarminfo >> %dir%body.txt
echo. >> %dir%body.txt
echo Datum: %date% >> %dir%body.txt
echo Uhrzeit: %time:~0,8% >> %dir%body.txt
echo. >> %dir%body.txt

if %1==0123456 set alias=Gruppenalarm

if %2==0 set subric=Einsatzbereitschaft
if %2==1 set subric=Einsatzalarm
if %2==2 set subric=Rueckruf Lst
if %2==3 set subric=Probealarm

echo %subric% %alias%:%3>> %dir%body.txt

echo %date% %time:~0,8%: PROGRAMMAUFRUF (%*) >> %dir%mail.log

%dir%wait.exe 2 /O
echo Email wird gesendet ...

%dir%sendEmail.exe -f %absender% -t %empfaenger% -u "%name% - Alarminfo vom %date%" -o message-file="%dir%body.txt" -o message-content-type=text -o message-header="X-Priority: 1" -s %smtp-server% -o username=%user% -o password=%passwort% -o tls=auto -l %dir%mail.log -q

echo. >> %dir%mail.log
echo Email gesendet ...

%dir%wait.exe 15 /O
del %dir%body.txt

:ende
exit